#---------------------------------------------------------------------------#
# File Name: MMS.awk                                                        #
# Description:  This awk program converts Markov diagrams into mathematica  #
#    equations. Given input files with two sections: transitional and       #
#    proability, this program outputs MTTDL and Variance equations in       #
#    mathematica notation.                                                  #
# Usage:  awk -f MMS.awk <input_file_name>                                  #
#                                                                           #
# University Of California, San Diego                                       #
# Computer Science Department                                               #
# Designer:  Andrew H. Nguyen                                               #
# Course:  Storage System 228B                                              #
# Last Modified:  June 6, 1997                                              #
#---------------------------------------------------------------------------#

BEGIN {
   error = 0
   numOfColumn = 0
   initRow = 0
   startProb = 0 
   startTrans = 0
   probCounter = 0
   mIsEmpty = 1 
}

1 == 1 { if (NF == 0) next }

/^[ \t]*[bB][eE][gG][iI][nN][ \t]+[pP][rR][oO][bB][aA][bB][iI][lL][iI][tT][yY]/ && (startProb == 0) {
   startProb = 1;next
}

/^[ \t]*[eE][nN][dD][ \t]+[pP][rR][oO][bB][aA][bB][iI][lL][iI][tT][yY]/ && (startProb == 1) {
   startProb = 2;next
}

/^[ \t]*[bB][eE][gG][iI][nN][ \t]+[tT][rR][aA][nN][sS][iI][tT][iI][oO][nN]/ && (startTrans == 0) {
   startTrans = 1;next
}

/^[ \t]*[eE][nN][dD][ \t]+[tT][rR][aA][nN][sS][iI][tT][iI][oO][nN]/ && (startTrans == 1) {
   startTrans = 2;next
}

startProb == 1 {
   if (NF < 2) { 
      print "Error: Invalid probability entry." 
      print "Line " NR ": "  $0
      error = 1
      exit
   } 
   if (probMatrix[$1] != "") {
      print "Error: Duplication of probability entry." 
      print "Line " NR ": "  $0
      error = 1
      exit
   }
   tempStr = $2
   for(i = 3;i<NF+1;i++) 
      tempStr = tempStr " " $i; 
   probMatrix[$1] = tempStr 
   probCounter++
   next
}

startTrans == 1 { 
   if (NF == 0) next
   if (NF < 3) {
      print "Error:  Required at least three fields per line entry." 
      print "Line " NR ": "  $0
      error = 1
      exit
   }
   
   if ($1 == $2) { 
      print "Error: Source and destination states are the same." 
      print "Line " NR ": "  $0
      error = 1
      exit
   } 

   if (Raw[$1$2] == 1) {
      print "Error: Duplicate transition entry." 
      print "Line " NR ": "  $0
      error = 1
      exit
   } else
      Raw[$1$2] = 1

   # TempStr = transition value
   TempStr = $3 
   for (i = 4; i < NF+1; i++) { TempStr = TempStr " " $i }
   if (diag[$1] == "")  diag[$1] = TempStr 
   else diag[$1] = diag[$1] " + " TempStr  

   if (diag1[$1] == "")  diag1[$1] = TempStr 
   else diag1[$1] = diag1[$1] " + " TempStr  

   states[$1] = 1
   input[$1 $2] = TempStr 
   source[$1] = 1
   dest[$2] = 1
   mIsEmpty = 0
}

END {
   if (error == 1) {exit}

   if (startTrans != 2) 
      { print "Error: No transition section found.";exit}
   if (mIsEmpty == 1) 
      { print "Error: No transtion entry found.";exit}

   ExistFail = 0
   for (item in dest) {
     if (source[item] != 1) { ExistFail++ }
   } 

   if (ExistFail == 0) 
      { print "Error: There exist no failure state.";exit }  

   if (ExistFail > 1  ) 
      { print "Error: There exist multiple failure states.";exit }  

   if (startProb == 0) 
      { print "Error: No probability section found.";exit}

   for (item in diag) diag[item] = "-(" diag[item] ")" 
   for (item in diag1) diag1[item] = "S + (" diag1[item] ")" 
 
   numOfState = 0
   for (curState in states)  numOfState++
   i = 0 
   for (curState in states) {
      i++ 
      pValue = ""
      p1Value = ""
      for (curColumn in states) {
         if (input[curColumn curState] == "") input[curColumn curState] = 0
         if (curState == curColumn) {
           pValue = pValue ", " diag[curState] 
           p1Value = p1Value ", " diag1[curState] 
         } else {
           pValue = pValue ", " input[curColumn curState] 
           p1Value = p1Value ", " input[curColumn curState] 
         }
      } 
      numOfColumn++
      M[numOfColumn] = "{ " substr(pValue,3,length(pValue)) " }"
      VarM[numOfColumn] = "{ " substr(p1Value,3,length(p1Value)) " }"
      P[numOfColumn] = curState 

      if (probMatrix[P[numOfColumn]] == "") {
         print "Error: No probability value for state " P[numOfColumn]"." ;
         exit 
      }  
   }

   print "M = {"
   print "\t "M[1]
   for (i = 2; i<numOfColumn+1; i++) { print "\t,"M[i] } 
   print "    }"

   print "VarM = {"
   print "\t "VarM[1]
   for (i = 2; i<numOfColumn+1; i++) { print "\t,"VarM[i] } 
   print "    }"

   tempStr = "{1"
   for (i=1;i<numOfState;i++) { tempStr = tempStr ",1"}  
   tempStr = tempStr "}"
   print "OneMatrix = " tempStr 
 
   tempStr = "" 
   VarOneMatrix = ""
   for (i =1;i<numOfColumn+1;i++) { 
      if (tempStr == "") {
         tempStr = "{" probMatrix[P[i]] "}"
         VarOneMatrix = "{1}"
      } else {
         tempStr = tempStr ",{" probMatrix[P[i]] "}" 
         VarOneMatrix = VarOneMatrix ",{1}"
      }
   }  
   tempStr = "{" tempStr "}"
   VarOneMatrix = "{" VarOneMatrix "}"
   print "VarOneMatrix = " VarOneMatrix  

   print "Prob = " tempStr
  
   tempStr = "" 
   tempStr = probMatrix[P[1]] 
   for (i =2;i<numOfColumn+1;i++) { 
       tempStr =  tempStr "," probMatrix[P[i]] 
   } 
   tempStr = "{" tempStr "}"
   print "VarProb = " tempStr
   print "SecondMoment = (Limit[(-2 VarProb . (D[(Inverse[VarM]),S])),S->0]) . VarOneMatrix"
   print "MTTDL = Simplify[- OneMatrix . Inverse[M] . Prob]"
   print "Variance = Simplify[SecondMoment - MTTDL^2]" 
}